433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Wireless and wired modules including Bluetooth, Ethernet, and IR kits.
admin
Site Admin
Posts: 734
Joined: Sun Aug 05, 2012 4:02 pm

433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by admin » Sun Mar 03, 2013 1:33 pm

Image

Order yours here

RECEIVER MODULE PARAMETERS:

Model: MX-05V
Working voltage: 5V DC quiescent current: 4mA
Receiver Frequency: 433.92MHZ
Receiver sensitivity:-105DB
Size: 30 * 14 * 7mm


TRANSMITTER MODULE PARAMETERS:

Model: MX-FS-03V
Transmission Distance :20-200 m (dependent on supply voltage)
Operating Voltage :3.5-12V
Dimensions: 19 * 19mm
AM transfer rate: 4Kb/s (4000 bits per second)
Transmission power: 10mW
Emission frequency: 433M


PINOUTS:

Image


NOTES:

When using an external antenna a 1/4 wavelength is recommended. Ideally use 50 impedance ohm single-core wire, the length of the antenna 433M is about 17cm (1/4 wavelength). When locating the receiver antenna keep it as far away as possible from shielded areas, high voltages, and any other possible interfering frequencies.


APPLICATIONS:

Remote control switch, receiver module, motorcycles, automobile anti-theft products, household anti-theft products, electric doors, shutter doors, windows, remote control socket, remote control the LED, remote control stereo, remote control electric gate, garage door remote control, remote control retractable doors, remote control volume gate, pan doors, remote control door opener, door closing device control system, remote control curtains, alarm system, alarm, remote control motorcycle, remote control electric cars, remote control such as MP3.

MX-FS-03V Schematic:

Image

MX-05V Schematic:

Image

Arduino VirtualWire library: http://www.pjrc.com/teensy/arduino_libr ... alWire.zip


ARDUINO TRANSMIT EXAMPLE

Code: Select all

/* FILE:    MXFS03V_433MHZ_MODULE_HCMODU0007_TRANSMIT_EXAMPLE.pde
   DATE:    03/03/13
   VERSION: 0.1
   AUTHOR:  Andrew Davies

This is an example of how to use the 433MHz wireless transmitter module 
(HCMODU0007) which is the Tx part of the tranmitter and receiver module pair.
This example makes use of the VirtualWire library written by Mike McCauley.
The sketch will read a value from the analogue input A0 and transmit it as 
2 bytes to the receiver module once every second.

Tx MODULE CONNECTIONS:

PIN  DESCRIPTION      ARDUINO PIN
1    GND              GND
2    VCC (3.5-12V)    VCC
3    TX DATA          D2


You may copy, alter and reuse this code in any way you like, but please leave 
reference to HobbyComponents.com in your comments if you redistribute this code. 

THIS SOFTWARE IS PROVIDED "AS IS". HOBBY COMPONENTS LTD MAKES NO WARRANTIES, WHETHER 
EXPRESS, IMPLIED OR STATUTORY, INCLUDING, BUT NOT LIMITED TO, IMPLIED WARRANTIES OF 
MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE, ACCURACY OR LACK OF NEGLIGENCE.
HOBBY COMPONENTS SHALL NOT, IN ANY CIRCUMSTANCES, BE LIABLE FOR ANY DAMAGES, 
INCLUDING, BUT NOT LIMITED TO, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES FOR ANY 
REASON WHATSOEVER.
*/


/*Include the VirtualWire library */
#include <VirtualWire.h>

/* Digital IO pin that will be used for sending data to the transmitter */
const int TX_DIO_Pin = 2;


void setup()
{
  pinMode(13, OUTPUT);
  /* Initialises the DIO pin used to send data to the Tx module */
  vw_set_tx_pin(TX_DIO_Pin);
  /* Set the transmit logic level (LOW = transmit for this 
     version of module)*/ 
  vw_set_ptt_inverted(true); 
  
  /* Transmit at 2000 bits per second */
  vw_setup(2000);	 // Bits per sec
}

/* Main program */
void loop()
{
  /* Temporarily holds the value read from analogue input A0 */
  unsigned int Data;
  /* The transmit buffer that will hold the data to be 
     transmitted. */
  byte TxBuffer[2];
  
  /* Read the analogue input A0... */
  Data = analogRead(A0);
  /* ...and store it as high and low bytes in the transmit 
     buffer */
  TxBuffer[0] = Data >> 8;
  TxBuffer[1] = Data;
  
  /* Turn on the LED on pin 13 to indicate that we are about 
    to transmit data */
  digitalWrite(13, HIGH); 
  /* Send the data (2 bytes) */
  vw_send((byte *)TxBuffer, 2);
  /* Wait until the data has been sent */
  vw_wait_tx(); 
  
  /* Turn off the LED on pin 13 to indicate that we have 
     now sent the data */
  digitalWrite(13, LOW); 
  
  /* Do nothing for a second. Lower this delay to send 
     data quicker */
  delay(1000);
}


ARDUINO RECEIVE EXAMPLE

Code: Select all

/* FILE:    MX05V_433MHZ_MODULE_HCMODU0007_RECEIVE_EXAMPLE.pde
   DATE:    03/03/13
   VERSION: 0.1
   AUTHOR:  Andrew Davies

This is an example of how to use the 433MHz wireless reciever module 
(HCMODU0007) which is the Rx part of the tranmitter and reciver module pair.
This example makes use of the VirtualWire library written by Mike McCauley.
This sketch in intended to be used with the Tx example code to recive analogue
input data sent from the transmitting Arduino. The received data is then output 
to the UART.

Rx MODULE CONNECTIONS:

PIN  DESCRIPTION      ARDUINO PIN
1    GND              GND
2    RX DATA          D2
3    RX DATA          N/A
4    VCC (5V)         VCC


You may copy, alter and reuse this code in any way you like, but please leave 
reference to HobbyComponents.com in your comments if you redistribute this code. 

THIS SOFTWARE IS PROVIDED "AS IS". HOBBY COMPONENTS LTD MAKES NO WARRANTIES, WHETHER 
EXPRESS, IMPLIED OR STATUTORY, INCLUDING, BUT NOT LIMITED TO, IMPLIED WARRANTIES OF 
MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE, ACCURACY OR LACK OF NEGLIGENCE.
HOBBY COMPONENTS SHALL NOT, IN ANY CIRCUMSTANCES, BE LIABLE FOR ANY DAMAGES, 
INCLUDING, BUT NOT LIMITED TO, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES FOR ANY 
REASON WHATSOEVER.
*/


/*Include the VirtualWire library */
#include <VirtualWire.h>

/* Digital IO pin that will be used for receiving data from the receiver */
const int RX_DIO_Pin = 2;

void setup()
{
    pinMode(13, OUTPUT);
    Serial.begin(9600);

    /* Initialises the DIO pin used to receive data from the Rx module */
    vw_set_rx_pin(RX_DIO_Pin);
    
    /* Receive at 2000 bits per second */
    vw_setup(2000);
    
    /* Enable the receiver */
    vw_rx_start(); 
}

/* Main program */
void loop()
{
  /* Set the receive buffer size to 2 bytes */
  uint8_t Buffer_Size = 2;
  
  /* Holds the recived data */
  unsigned int Data;
  
  /* The receive buffer */
  uint8_t RxBuffer[Buffer_Size];

    /* Has a message been received? */
    if (vw_get_message(RxBuffer, &Buffer_Size)) // Non-blocking
    {
        /* If so, then turn on the LED connected to DIO 13 
           to indicate this */
        digitalWrite(13, HIGH); 
	
        /* Store the received high and low byte data */
        Data = RxBuffer[0] << 8 | RxBuffer[1];

        /* Output this data to the UART */
	Serial.print("Analogue pin A0: ");
        Serial.println(Data);
	
        /* Turn off the LED on pin 13 to indicate that the 
           data has now been received */
        digitalWrite(13, LOW);
    }
}

VirtualWire Library:

A snapshot of this library can be downloaded from here (please log in to download)
VirtualWire-1.14.zip
The latest version of this library can be downloaded from the following website:

https://www.pjrc.com/teensy/td_libs_VirtualWire.html


FAQ

Can I transmit to more than one receiver?

Yes, all modules operate on the same channel so any receiver will receive data from any transmitter in range.

Can I receive data from more than one transmitter?

Yes, see above.

What is the fastest data rate I can send using these modules?

You can seen a maximum of 4000 (4Kb/s) bits per second. See comment below.


Can I use this module to send serial data?

Yes, but there are a couple of considerations:

First of all the Tx output pin of the receiver is normally low which means that your start bit will have to be a logic high to be detected by your application. This means a standard serial interface may not work without modification.

Secondly the module has a limited data rate of 4000 bits per second. The main limiting factor is that there is a fixed delay on the rising edge of the Tx pin. This delay get more significant as the data rate is increased which causes the logic '1's' to get narrower. Beyond 4Kb/s the logic 1's start to become too narrow and may cause them to be seen as 0's by the receiving hardware. The reciver's Tx pin will also take approximately 55ms to return low again after receiving data.
You do not have the required permissions to view the files attached to this post.

snapper
Posts: 3
Joined: Sat Aug 03, 2013 6:05 pm

Re: 433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by snapper » Sat Aug 03, 2013 6:16 pm

hello,

work this module with HT-12D/E for a simple wireless switcher ?

http://www.holtek.com/pdf/consumer/2_12ev120.pdf

http://www.holtek.com/pdf/consumer/2_12dv120.pdf

Image

regards

andrew
Site Admin
Posts: 865
Joined: Sun Aug 05, 2012 4:15 pm

Re: 433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by andrew » Sun Aug 04, 2013 7:14 am

From what I can see from the datasheet the HT12E (no carrier version) should work fine. Data is clocked out at 3KHz which these modules should just about be able handle.
Comments made by this poster do not necessarily reflect the views of Hobby Components Ltd.

snapper
Posts: 3
Joined: Sat Aug 03, 2013 6:05 pm

Re: 433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by snapper » Sun Aug 04, 2013 8:40 am

I found now other cheaper decoder IC´s, PT2262 / PT2272.

There are also RF module, as these are already integrated !

Image

http://www.princeton.com.tw/Portals/0/P ... PT2272.pdf

http://www.princeton.com.tw/Portals/0/P ... 2262_5.pdf

Dick Whittington

Re: 433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by Dick Whittington » Wed Aug 14, 2013 4:36 pm

@ snapper. Where do you get these newer modules from please?

snapper
Posts: 3
Joined: Sat Aug 03, 2013 6:05 pm

Re: 433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by snapper » Wed Aug 14, 2013 5:06 pm

@Dick Whittington

pls send PM

andrew
Site Admin
Posts: 865
Joined: Sun Aug 05, 2012 4:15 pm

Re: 433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by andrew » Sat Aug 17, 2013 1:51 pm

Just to let you know that we now have the PT2262 & PT2272 modules (non-latching version) on order and we will be stocking them soon.
Comments made by this poster do not necessarily reflect the views of Hobby Components Ltd.

lardconcepts
Posts: 7
Joined: Thu Sep 05, 2013 8:33 pm

Re: 433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by lardconcepts » Sat Sep 07, 2013 1:12 pm

Just to let you know that both in the shop and in this thread, the "pinout" image at http://www.hobbycomponents.com/image/da ... Pinout.png is broken.

I've managed to find the pinouts elsewhere but just thought I'd let you know :)

andrew
Site Admin
Posts: 865
Joined: Sun Aug 05, 2012 4:15 pm

Re: 433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by andrew » Sun Sep 08, 2013 2:46 pm

Thanks for pointing this out. We moved to a different hosting company a little while back and it broke one or two links. This should be fixed now.
Comments made by this poster do not necessarily reflect the views of Hobby Components Ltd.

nigelmercier
Posts: 14
Joined: Sun Jan 05, 2014 12:40 pm

Re: 433MHz Wireless Modules MX-FS-03V & MX-05 (HCMODU0007)

Post by nigelmercier » Sun Jan 05, 2014 12:42 pm

Has anyone got datasheets for these MX-FS-03V & MX-05 modules, or C code for a PIC?

Post Reply